[GAP Forum] Extension of sporadic group

[Thomas Breuer]

Dear GAP Forum,

the outer automorphism groups of sporadic simple groups
have order at most two.
Thus we can get the names of the non-perfect cyclic upward extensions
of sporadic simple groups as follows.

Get the names of the sporadic simple groups, ...

    gap> simpnames:= AllCharacterTableNames( IsSporadicSimple, true,
    >                    IsDuplicateTable, false );
    [ "B", "Co1", "Co2", "Co3", "F3+", "Fi22", "Fi23", "HN", "HS", "He", "J1", 
      "J2", "J3", "J4", "Ly", "M", "M11", "M12", "M22", "M23", "M24", "McL", 
      "ON", "Ru", "Suz", "Th" ]

... get the names of their automorphism groups, ...

    gap> autnames:= AllCharacterTableNames( IsSporadicSimple, true,
    >                    IsDuplicateTable, false,
    >                    OfThose, AutomorphismGroup );
    [ "B", "Co1", "Co2", "Co3", "F3+.2", "Fi22.2", "Fi23", "HN.2", "HS.2", 
      "He.2", "J1", "J2.2", "J3.2", "J4", "Ly", "M", "M11", "M12.2", "M22.2", 
      "M23", "M24", "McL.2", "ON.2", "Ru", "Suz.2", "Th" ]

... and get the names of the proper extensions.

    gap> extnames:= Difference( autnames, simpnames );
    [ "F3+.2", "Fi22.2", "HN.2", "HS.2", "He.2", "J2.2", "J3.2", "M12.2", 
      "M22.2", "McL.2", "ON.2", "Suz.2" ]

If the question is to get a faithful representation of these groups in GAP
then I would recommend using the ATLAS of Group Representations.
With the help of the GAP package `AtlasRep',
we can fetch representations with the function `AtlasGroup'.

    gap> AtlasGroup( "M12.2" );
    Group([ (1,4)(2,17)(3,15)(5,18)(6,19)(7,12)(8,10)(9,21)(11,13)(14,16)(20,23)
    (22,24), (2,18,23)(3,19,14)(4,11,21)(5,10,16)(7,22,13)(17,24,20) ])

Thus we can get a representation for each of the groups in question with

    gap> reps:= List( extnames, AtlasGroup );;

This list gives us a permutation representation in all cases except for HN.2,
where just a matrix representation is available.
A permutation representation for HN.2 can be found for example via the
overview list at

    http://www.math.rwth-aachen.de/~Thomas.Breuer/atlasverify/overview.html

All the best,
Thomas


On Mon, May 07, 2018 at 07:57:28AM +0330, Sara Dikson wrote:
> Dear Forum
> I need the cyclic extensions of sporadic groups S (for example M_(11).2) as
> a gap programs.
> I would be grateful if you guided me through this.
> 
> Best regards
> Sara