# [GAP Forum] A question about StructureDescription

Stefan Kohl kohl at univlora.edu.al
Mon Jan 11 22:52:10 GMT 2010

Dear Forum,

I would like to know how we can  understand the diversity between
> StructureDescription(SmallGroup(81,3));
> StructureDescription(SmallGroup(81,8));
> and StructureDescription(SmallGroup(81,14)).
> Of course all of them have the presentation  "(C9 x C3) : C3" with
> different  semi direct products
> which induced by \phi : C3----> Aut(C9 x C3).
> How we can exactly find the structure of  \phi in all cases?
>

You can proceed as follows:

1. Define the semidirect factors C3 and C9 x C3

gap> C3 := CyclicGroup(3);
<pc group of size 3 with 1 generators>
gap> C9C3 := DirectProduct(CyclicGroup(9),CyclicGroup(3));
<pc group of size 27 with 3 generators>

2. Find all embeddings of C3 into Aut(C9 x C3)

gap> phis := IsomorphicSubgroups(AutomorphismGroup(C9C3),C3);
[ [ f1 ] -> [ [ f1, f3 ] -> [ f1, f2*f3 ] ],
[ f1 ] -> [ [ f1, f3 ] -> [ f1*f2, f3 ] ],
[ f1 ] -> [ [ f1, f3 ] -> [ f1*f3, f3 ] ],
[ f1 ] -> [ [ f1, f3 ] -> [ f1*f3, f2*f3 ] ],
[ f1 ] -> [ [ f1, f3 ] -> [ f1*f3, f2^2*f3 ] ] ]

3. Form the corresponding semidirect products

gap> semidirectprods := List(phis,phi->SemidirectProduct(C3,phi,C9C3));
[ <pc group of size 81 with 4 generators>,
<pc group of size 81 with 4 generators>,
<pc group of size 81 with 4 generators>,
<pc group of size 81 with 4 generators>,
<pc group of size 81 with 4 generators> ]

4. Compute their group ID's and StructureDescription's

gap> List(last,IdGroup);
[ [ 81, 14 ], [ 81, 13 ], [ 81, 3 ], [ 81, 8 ], [ 81, 9 ] ]
gap> List(last2,StructureDescription);
[ "(C9 x C3) : C3", "C3 x (C9 : C3)", "(C9 x C3) : C3", "(C9 x C3) : C3",
"(C9 x C3) : C3" ]

Actually you see that the 5 semidirect products are pairwise nonisomorphic,
and that there is a 4th group getting the same StructureDescription.
For another group (the second in the list), StructureDescription prefers
another
decomposition. This is since that group can be decomposed into nontrivial
direct factors, and since StructureDescription follows the rule to decompose
into direct factors first.

Hope this helps,

Stefan Kohl

---------------------------------------------
Dr. Stefan Kohl
Universiteti "Ismail Qemali" Vlore
Lagjja: Pavaresia
Vlore / Albania

E-mail: kohl at univlora.edu.al
Web:    http://univlora.edu.al/personel/kohl/
---------------------------------------------