[GAP Forum] reza orfi-p group with some propertise

[Bettina Eick]

Dear GAP Forum,
Dear Reza Orfi,

the group enclosed below is of the type you want to have, I think.

Also enclosed below is a short GAP programm which can be used to
find groups of your desired type. It is based on the ANUPQ share
package which can be used to list p-groups systematically.

Best wishes,
            Bettina

#############################################################################
A group of order 3^7 with the following polycyclic presentation:

g1 ^ 3 = id
g2 ^ 3 = id
g3 ^ 3 = g6^2*g7^2
g4 ^ 3 = g7^2
g5 ^ 3 = g7
g6 ^ 3 = id
g7 ^ 3 = id
g2 ^ g1 = g2*g3
g3 ^ g1 = g3*g4
g3 ^ g2 = g3*g5
g4 ^ g1 = g4*g6
g4 ^ g2 = g4*g6
g4 ^ g3 = g4*g7^2
g5 ^ g1 = g5*g6*g7
g5 ^ g2 = g5*g6*g7^2
g5 ^ g3 = g5*g7^2
g6 ^ g1 = g6*g7
g6 ^ g2 = g6*g7^2

Then G' = Phi(G) = < g3, .., g7 >,
     Z(G) = < g4 g5^2 g6 > is cyclic of order 9, and
     the coclass of G is 2.

#############################################################################
RequirePackage("anupq");

CoclassPGroup := function( G )
    return Length(Factors(Size(G))) - Length(LowerCentralSeries(G))+1;
end;

TryPrime := function(p)
    local i, todo, news, H, desc, K;
    todo := [AbelianGroup([p,p])];
    i := 2;
    while true do
        i := i+1;
        Print("start layer ",i," with ",Length(todo)," groups \n");
        news := [];
        for H in todo do

            if CoclassPGroup(H) = 1 then
                desc := PqDescendants( H : Stepsize := [1,2] );
                desc := Filtered(desc,x->Index(x,DerivedSubgroup(x))=p^2);
                for K in desc do
                    if AbelianInvariants(Center(K)) = [p^2] and
                       CoclassPGroup(K) = 2 then
                        return K;
                    fi;
                od;
                Append(news, Filtered( desc, IsCapable ));
                Print("\n");
            fi;

            if CoclassPGroup(H) = 2 then
                desc := PqDescendants( H : Stepsize := 1 );
                desc := Filtered(desc, x->Index(x,DerivedSubgroup(x))=p^2);
                for K in desc do
                    if AbelianInvariants(Center(K)) = [p^2] then
                        return K;
                    fi;
                od;
                Append(news, Filtered( desc, IsCapable ));
                Print("\n");
            fi;

        od;
        todo := StructuralCopy(news);
        if Length(todo) = 0 then return; fi;
    od;
end;