[GAP Forum] Character values on Sylow subgroups

Thomas Breuer thomas.breuer at math.rwth-aachen.de
Thu Jan 6 08:58:23 GMT 2005


Dear GAP Forum,

Vahid Dabbaghian-Abdoly wrote

> Using the Gap character table library, is it possible to
> compute character values of a group G on a Sylow subgroup of G?
> In particular I am looking for character values of the groups
> "L4(4)" and "L4(5)" on Sylow 2-subgroup and Sylow 5-subgroup,
> respectively.

If I understand the question right then the aim is to restrict characters
of G to the character table of a Sylow p-subgroup P of G.

If the character table of P is needed but not available
in the GAP Character Table Library
--which is the case for the two groups G in question--
then first one has to produce the character table of P,
presumably from a representation of P.

As has been mentioned in the answer by Mowsey to the GAP Forum,
computing the character table of a moderately sized p-group with
GAP's standard methods is easy.
The problem is then to determine the class fusion between the table
that was computed from P and the library table of G.
The combinatorial approach used by the GAP function `PossibleClassFusions'
is not suitable for this situation,
and as far as I know, no description of the class representatives in
the library table of G in terms of standard generators of G is available.
What one can try in this situation is either to compute the character
table of G from the group (which in this case requires extensions of
the standard methods for being efficient)
or to divide the problem into smaller problems.

If one is interested in restricting characters of G = L4(4) to its
Sylow 2-subgroup P then using the intermediate group N_G(P) solves the
problem.
Here is a GAP session for this example (which needed less than a minute
on my computer).

    gap> g:= PSL(4,4);;
    gap> s:= SylowSubgroup( g, 2 );;
    gap> n:= Normalizer( g, s );;
    gap> tg:= CharacterTable( "L4(4)" );;
    gap> ts:= CharacterTable( s );;
    gap> tn:= CharacterTable( n );;
    gap> sfusn:= FusionConjugacyClasses( ts, tn );;
    gap> nfusg:= PossibleClassFusions( tn, tg );;
    gap> sfusg:= Set( List( nfusg, map -> map{ sfusn } ) );;
    gap> Length( sfusg );
    1

Now for example the decomposition of the first nontrivial irreducible
character of G into irreducibles of P can be computed as follows.

    gap> chi:= Irr( tg )[2];
    Character( CharacterTable( "L4(4)" ), [ 84, 20, 4, 21, 21, 9, 6, 4, 0, 
      -1, -1, 4, 4, -1, 5, 5, 5, 5, 1, 2, 0, 0, 0, 0, -1, -1, 0, 0, 1, 1, 4, 
      4, 4, 4, -1, -1, -1, -1, 1, 1, 1, 1, 1, 1, -1, -1, -1, -1, 0, 0, 0, 0, 
      0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, -1, -1, -1, -1, -1, 
      -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ] )
    gap> rest:= chi{ sfusg[1] };
    [ 84, 20, 20, 20, 20, 20, 20, 20, 20, 20, 20, 4, 4, 4, 4, 4, 4, 20, 4, 
      4, 4, 4, 4, 4, 20, 4, 4, 4, 4, 4, 4, 20, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 
      4, 4, 4, 4, 4, 20, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 20, 4, 
      4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 20, 4, 4, 4, 4, 4, 4, 4, 0, 
      0, 0, 4, 0, 0, 0, 4, 0, 0, 0, 20, 4, 4, 4, 4, 4, 4, 4, 0, 0, 0, 4, 0, 
      0, 0, 4, 0, 0, 0, 20, 4, 4, 4, 4, 4, 4, 4, 0, 0, 0, 4, 0, 0, 0, 4, 0, 
      0, 0 ]
    gap> MatScalarProducts( ts, Irr( ts ), [ rest ] );
    [ [ 3, 1, 1, 1, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
          0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
          0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 
          0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
          0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 
          0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 
          0, 0, 0 ] ]

(For G = L4(5) and p = 5, the only difference is that the class fusion
is not uniquely determined but only unique up to table automorphisms
of the character tables in question;
one ends up with a list of 16 equivalent possibilities.)

All the best,
Thomas




More information about the Forum mailing list