[GAP Forum] subgroup of direct product

[Alexander Konovalov]

Dear Parth Dixit, dear GAP Forum

Let me suggest the following:

First the direct product

gap> g:=SymmetricGroup(5);
Sym( [ 1 .. 5 ] )
gap> dp:=DirectProduct(g,g);
Group([ (1,2,3,4,5), (1,2), (6,7,8,9,10), (6,7) ])

and embeddings into its components:

gap> f1:=Embedding(dp,1);
1st embedding into Group([ (1,2,3,4,5), (1,2), (6,7,8,9,10), (6,7) ])
gap> f2:=Embedding(dp,2);
2nd embedding into Group([ (1,2,3,4,5), (1,2), (6,7,8,9,10), (6,7) ])

Now your groups:

gap> h1:=SymmetricGroup(3);
Sym( [ 1 .. 3 ] )
gap> h2:=DihedralGroup(IsPermGroup,8);
Group([ (1,2,3,4), (2,4) ])

And  their images under this embeddings (you see that these images are
subgroups of the direct product):

gap> k1:=Image(f1,h1);
Group([ (1,2,3), (1,2) ])
gap> IsSubgroup(dp,k1);
true

gap> k2:=Image(f2,h2);
Group([ (6,7,8,9), (7,9) ])
gap> IsSubgroup(dp,k2);
true

But even now their direct product can not be calculated as follows:

gap> s:=DirectProduct(k1,k2);
Group([ (1,2,3), (1,2), (4,5,6,7), (5,7) ])
gap> IsSubgroup(dp,s);
false

AND HERE IS THE CORRECT APPROACH:

gap> s:=ClosureGroup(k1,k2);
Group([ (2,3), (1,2,3), (6,7,8,9), (7,9) ])
gap> IsSubgroup(dp,s);
true


Hope this helps,

Sincerely yours,
Alexander Konovalov


On Tuesday, January 13, 2004 at 8:27:55 PM 
parth dixit <parth_dixit at da-iict.org> wrote:

> hi,
>    I am trying to form a subgroup of Direct product of two groups by 
> taking direct product of subgroups of the original groups.But it is 
> giving me error,I tried using AsSubgroup too but it failed.Please help 
> me.
gap>> G:=SymmetricGroup(5);;
gap>> H1:=SymmetricGroup(3);;
gap>> H2:=DihedralGroup(IsPermGroup,8);;
gap>> gg:=DirectProduct(G,G);;
gap>> hh:=DirectProduct(H1,H2);;
gap>> IsSubgroup(gg,hh);
> false
>                        thanks
>                            parth

> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum