[GAP Forum] Generating M11 via rational conjugacy classes.

Max Horn max at quendi.de
Wed Aug 2 19:58:45 BST 2017


Dear John,

> On 02 Aug 2017, at 12:47, John Simons <johnasimons at outlook.com> wrote:
> 
> Dear all,
> 
> I'm currently new to GAP and computer algebra systems and was wondering whether anyone knew of the easiest method to achieve the following.
> 
> Suppose I have a finite simple group - let us take $M_{11}$ and let $C_1, C_2, C_3$ be a triple of rational conjugacy classes ( if necessary, for the definition of rationality, see https://math.stackexchange.com/questions/218302/a-conjugacy-class-c-is-rational-iff-cn-in-c-whenever-c-in-c-and-n-is-co).
> 
> I would like to find explicit computations in GAP (or another system), such that I can find a triple of elements $g_1, g_2, g_3$ where $g_i \in  C_i$ satisfies $g_1g_2g_3 = 1$ and $M_{11}$ $\cong$ $<g_1,g_2,g_3>$.
> 
> I know GAP has the command which allows one to see the standard generators of $M_{11}$ in cycle notation, however, I cannot seem to find an easy way to do the above. There is a command to allow one to obtain the conjugacy classes of $M_{11}$ and also rational conjugacy classes in cycle notation (though I'm unaware of how to convert this into ATLAS notation such as $1A, 2A$ etc.)
> 
> Essentially, does anyone know how to run through rational conjugacy classes and arbitrarily take an element from three individual classes under the restriction places above; that the product of the three elements must be identity?  Perhaps the fact that we can rewrite $g_3 = (g_1g_2)^{-1}$ simplifies the computational procedure?

Absolutely. First, simplify this further: If a triple (g_1, g_2, g_3) has the require properties, then so does any of its conjugates. So it suffices to pick in the first one element g1. Then, let g2 run through all elements of the second class. This then determines g3 uniquely, and you just have to check if it lies in the third class. Finally, you have to check that M11 is generated by g1 and g2 (the element g3 is irrelevant for this).

One can improve this further, but for M11 the above is enough. Try this:

findNiceTriple := function(G, cls1, cls2, cls3)
    local g1, g2, g3;
    g1 := Representative(cls1);
    for g2 in cls2 do
        g3 := (g1*g2)^-1;
        if g3 in cls3 and M11 = Group(g1, g2) then
            return [g1, g2, g3];
        fi;
    od;
    return fail;
end;

Then for example:

gap> M11:=MathieuGroup(11);
Group([ (1,2,3,4,5,6,7,8,9,10,11), (3,7,11,8)(4,10,5,6) ])
gap> rc:=RationalClasses(M11);;
gap> Length(rc);
8
gap> findNiceTriple(M11, rc[2], rc[5], rc[8]);
[ (1,8)(3,9)(5,7)(10,11), (1,7,6,3,4,2,11,9,5,8,10), (1,11,2,4,9,10)(3,6,5)(7,8) ]
gap> findNiceTriple(M11, rc[8], rc[8], rc[8]);
[ (1,3,4,9,5,11)(2,6,10)(7,8), (1,4,7,5,10,9)(2,6,11)(3,8), (1,4,11,2,5,8)(3,7)(6,10,9) ]


> 
> What I eventually would like to obtain is that the commands eventually spit out:
> 
> "The conjugacy classes $2A, 4A$ and $11A$ are a triple of rational conjugacy classes satisfying the above".

Replacing rational by conjugacy classes above is of course trivial.
Most classes of M11 are uniquely determine by their size. leaves the two classes of size 8, resp. 11. I think the AtlasRep package can help you with identifying these, but I am not an expert on that.


Cheers,
Max


More information about the Forum mailing list