[GAP Forum] 3.M_{22}:2 on 990 points

[Frank Lübeck]

On Tue, Nov 15, 2016 at 07:59:48PM +0000, Bailey, Robert F. wrote:
> Dear forum,
> 
> The group 3.M_{22}:2 has a rank-9 imprimitive permutation representation
> of degree 990. (This is the full automorphism group of the
> distance-transitive Ivanov-Ivanov-Faradjev graph.) I would like to
> construct this group in GAP.
> 
> The www ATLAS gives a matrix representation of this group in
> characteristic 2; however, applying "IsomorphismPermGroup" to this matrix
> group gives a group of degree 693.
> 
> Does anyone have a suggestion for how to obtain the degree 990 representation?
> 
> Thanks,
> Robert Bailey.

Dear Robert, dear Forum,

[When I wanted to send this reply I have seen that Jürgen has already sent a
very similar solution.  Nevertheless, I send my as well because it uses
less knowledge about the relation the representations of M22.2 and 3.M22.2
in the ATLAS and some other GAP commands. Here it is:]

The www ATLAS does not only have a matrix representation for your group
but it also contains information for generating its maximal subgroups.
Use, for example BrowseAtlasInfo to find this out and to get some
information on the maximal subgroups. Lets take the smallest maximal
subgroup which may contain a group of the right order which may be the
stabilizer of a point in the permutation representation you are looking for:

gap> info:=BrowseAtlasInfo("3.M22.2");  # select the 7 maximal subgroups
[ rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", "M22d2G1-max1W1", 1 ], size := 1330560, 
      standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", "M22d2G1-max2W1", 1 ], size := 120960, 
      standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", "M22d2G1-max3W1", 1 ], size := 34560, 
      standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", "M22d2G1-max4W1", 1 ], size := 11520, 
      standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", [ "M22d2G1-max5W1", "M22.2" ], 1 ], 
      size := 8064, standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", "M22d2G1-max6W1", 1 ], size := 4320, 
      standardization := 1 ), 
  rec( groupname := "3.M22.2", 
      identifier := [ "3.M22.2", [ "M22d2G1-max7W1", "M22.2" ], 1 ], 
      size := 3960, standardization := 1 ) ]
gap> g := AtlasGroup("3.M22.2");
<matrix group of size 2661120 with 2 generators>
gap> q := Size(g)/990;
2688
gap> Filtered([1..7], i-> info[i].size mod q = 0);
[ 1, 2, 5 ]
gap> m := AtlasSubgroup(g, 5);;
gap> maxes := List(ConjugacyClassesMaximalSubgroups(m), Representative);;
gap> u := First(maxes, x-> Size(x) = q);
<group of 12x12 matrices of size 2688 over GF(2)>
gap> act := FactorCosetAction(g,u);
CompositionMapping( <action epimorphism>, <action isomorphism> )
gap> niceg := Image(act);
<permutation group of size 2661120 with 2 generators>
gap> LargestMovedPoint(niceg);
990
gap> st := Stabilizer(niceg, 1);
<permutation group of size 2688 with 4 generators>
gap> Length(Orbits(st, [1..990]));
9

Is niceg the permutation group you are looking for?

With best regards,
    Frank

-- 
///  Dr. Frank Lübeck, Lehrstuhl D für Mathematik, Pontdriesch 14/16,
\\\                    52062 Aachen, Germany
///  E-mail: Frank.Luebeck at Math.RWTH-Aachen.De
\\\  WWW:    http://www.math.rwth-aachen.de/~Frank.Luebeck/