[GAP Forum] Cohomology of nontrivial G-modules?

[Ellis, Grahamj]

Hi Benoit,

On Wed, Nov 11, 2015 at 10:52:29AM -0500, Benoit Jacob wrote:
> > I need to compute cohomology groups of the form
> >
> >     H^n(G, A)
> >
> > where G is a finite group and A is a nontrivial G-module. More
> > specifically, A is a finite-dimensional vector space over Z/2Z on which G
> > acts non-trivially.
> >
> > Any example code would be greatly appreciated;

I think the answer to you question depends very much on the type of input (how large is your n? what nice properties does G have? what is the dimension of the module A?) and on the required output (do you only want the abelian invariants of the cohomology group, or do you also need things like explicit cocycles?). For n=1,2 you might have most success using the Coho package. If you send me details I'd be glad to try to help.

The following example code calculates the abelian invariants of 

H^6(G,A)=Z_2 x Z_2 x Z_2 x Z_2 x Z_5

for G=S_5 the symmetric group of degree 5 and A the vector space of dimension 5 over GF(2) with permutation action. But with a tiny bit of programming (involving Sylow subgroups) this example can be significantly improved.  

gap> G:=SymmetricGroup(5);;
gap> 
gap> V:=AbelianGroup(IsPcGroup,[2,2,2,2,2]);;
gap> gensV:=GeneratorsOfGroup(V);;
gap> w:=GroupHomomorphismByImages(V,V,gensV,gensV{[2,1,3,4,5]});;
gap> x:=GroupHomomorphismByImages(V,V,gensV,gensV{[1,3,2,4,5]});;
gap> y:=GroupHomomorphismByImages(V,V,gensV,gensV{[1,2,4,3,5]});;
gap> z:=GroupHomomorphismByImages(V,V,gensV,gensV{[1,2,3,5,4]});;
gap> G1:=Group([w,x,y,z]);;
gap> 
gap> iso:=GroupHomomorphismByImages(G,G1,[(1,2),(2,3),(3,4),(4,5)],[w,x,y,z]);;
gap> action:=function(g,v); return v^Image(iso,g^-1); end;;  #HAP uses left actions!!!
gap> 
gap> A:=GOuterGroup();;
gap> SetActedGroup(A,V);;
gap> SetActingGroup(A,G);;
gap> SetOuterAction(A,action);;
gap> 
gap> R:=ResolutionFiniteGroup(G,7);;
gap> C:=HomToGModule(R,A);;
gap> 
gap> H6:=Cohomology(C,6);
[ 2, 2, 2, 2, 2 ]


All the best,

Graham

School of Mathematics, Statistics & Applied Mathematics
National University of Ireland, Galway
University Road,
Galway
Ireland

http://hamilton.nuigalway.ie
tel: 091 493011