[GAP Forum] Order and Size

Benjamin Sambale benjamin.sambale at gmail.com
Thu Jan 30 07:46:09 GMT 2014


Thanks for the fix! It seems to work now.

Benjamin

Am 29.01.2014 17:30, schrieb Max Horn:
> Dear Benjamin,
>
> On 29.01.2014, at 16:27, Benjamin Sambale <benjamin.sambale at gmail.com> wrote:
>
>> Dear GAP users,
>>
>> I'm using GAP 4.7.2 and just ran into the following strange behavior:
>>
>> G:=AbelianGroup([4,4,4]);;
>> A:=AutomorphismGroup(G);;
>> x:=First(A,a->Order(a)<>Size(Group(a)));
>> [ f1*f2*f3, f5, f1*f2*f6 ] -> [ f1, f1*f2*f4*f5*f6, f2*f3*f6 ]
>>
>> I thought that the order of an element is the same as the size of the generated group?? Indeed:
>>
>> x^Order(x);
>> Pcgs([ f1, f2, f3, f4, f5, f6 ]) -> [ f1, f2, f3, f4, f4*f5*f6, f6 ]
>>
>> Any ideas?
> This is a bug in GAP :-(. It will be fixed in the next GAP release. In the meantime, you can paste this code into your GAP session to fix the issue:
>
> InstallMethod(Order,"for automorphisms",true,[IsGroupHomomorphism],0,
> function(hom)
> local map,phi,o,lo,i,start,img;
>    o:=1;
>    phi:=hom;
>    map:=MappingGeneratorsImages(phi);
>    i:=1;
>    while i <= Length(map[1]) do
>      lo:=1;
>      start:=map[1][i];
>      img:=map[2][i];
>      while img<>start do
>        img:=ImagesRepresentative(phi,img);
>        lo:=lo+1;
>        # do the bijectivity test only if high local order, then it does not
>        # matter
>        if lo=1000 and not IsBijective(hom) then
>          Error("<hom> must be bijective");
>        fi;
>      od;
>      if lo>1 then
>        o:=o*lo;
>        if i<Length(map[1]) then
>          phi:=phi^lo;
>          map:=MappingGeneratorsImages(phi);
>          i:=0;
>        fi;
>      fi;
>      i:=i+1;
>    od;
>    return o;
> end);
>
>
> Thanks for the report,
> Max




More information about the Forum mailing list