[GAP Forum] Question about symmetric group of nine letters

[Thomas Breuer]

Dear Forum,

Hamid Shahverdi had asked the following question (in June).

> How can one try by gap to show that
> 
> If a centerless group G of order 9! has the following properties, then it
> is isomorphic to S_9
> 1) size of all conjugacy classes are equal to the one in S_9.
> 2) the order of all maximal abelian subgroups are equal to the one in S_9.

First of all, sorry for the late reply.
Below is a sketch of a proof.
(If one wants then one can replace some of the statements about small simple
groups by combinatorial computations.)

All the best,
Thomas


Claim:
The symmetric group $S_9$ on nine points is determined by its order,
its set of conjugacy class lengths,
and the fact that it has trivial centre.

Proof:
Let $G$ be a finite group of order $|S_9| = 9!$, with trivial centre,
and such that the length of each conjugacy class of $G$ is equal to
the length of a conjugacy class of $S_9$.

First we observe that no sum of class lengths of $S_9$
(with multiplicities, where the multiplicity of $1$ is one)
is equal to a prime power that divides $9!$.

    gap> order:= Factorial( 9 );
    362880
    gap> facts:= Collected( Factors( order ) );
    [ [ 2, 7 ], [ 3, 4 ], [ 5, 1 ], [ 7, 1 ] ]
    gap> pparts:= List( facts, pair -> pair[1]^pair[2] );
    [ 128, 81, 5, 7 ]
    gap> ccl:= Set( SizesConjugacyClasses( CharacterTable( "S9" ) ) );
    [ 1, 36, 168, 378, 756, 945, 1260, 2240, 2520, 3024, 3360, 7560, 9072,
      10080, 11340, 15120, 18144, 20160, 24192, 25920, 30240, 40320, 45360 ]

This means that $G$ is not solvable, and does not contain a solvable normal
subgroup.
Thus $G$ contains a nonabelian simple subgroup $S$, say.
Since the order of $S$ is divisible by $5$ or $7$,
which divide the order of $G$ only once, no proper power of $S$ can occur
as a subgroup of $G$, that is, $G$ contains a nonabelian simple normal
subgroup $N$, say.

Next we compute a representative of each isomorphism type of those
nonabelian simple groups whose order divides $9!$.

    gap> cand:= Filtered( DivisorsInt( order ), i -> not IsPrimeInt( i ) );;
    gap> simp:= AllSmallNonabelianSimpleGroups( cand );
    [ A5, PSL(2,7), A6, PSL(2,8), A7, PSU(3,3), A8, PSL(3,4), PSp(4,3), A9 ]

Finally we compute, for each simple candidate $S$,
the class lengths of involutions in $S$.

    gap> for g in simp do
    >      gccl:= ConjugacyClasses( g );
    >      filt:= Filtered( gccl, x -> Order( Representative( x ) ) = 2 );
    >      Print( g, ":\n", List( filt, Size ), "\n" );
    >    od;
    A5:
    [ 15 ]
    PSL(2,7):
    [ 21 ]
    A6:
    [ 45 ]
    PSL(2,8):
    [ 63 ]
    A7:
    [ 105 ]
    PSU(3,3):
    [ 63 ]
    A8:
    [ 210, 105 ]
    PSL(3,4):
    [ 315 ]
    PSp(4,3):
    [ 45, 270 ]
    A9:
    [ 378, 945 ]

We see that only the alternating group $A_9$ on nine points has classes
of involutions such that some union can form a class of involutions in $G$.
Thus $G$ has a normal subgroup isomorphic to $A_9$.
Since the centralizer of this subgroup is trivial,
$G$ is isomorphic to the symmetric group $S_9$.