[GAP Forum] question

[Bettina Eick]

Dear Elaheh Khamseh,

the Schur multiplier of a finite p-group (or of a polycyclic group in
general) can be computed in GAP with the function 'SchurMultiplicator' 
of the Polycyclic package. This returns the abelian invariants of the 
SchurMultiplier. It requires a PcpGroup as input.

The groups of order p^5 are available as part of the SmallGroups library of 
GAP for every prime p. It is also not difficult to construct your desired 
groups directly; see for example the function 'SpecialSplitExtensions' 
enclosed below.

I hope that this helps you towards your questions and towards an
investigation of the Schur multipliers of your considered groups.

Best wishes,

Bettina

SpecialSplitExtensions := function(p)
     local cl, grps;

     # get conjugacy classes of elements of order p in GL(4,p)
     cl := ConjugacyClasses(GL(4,p));
     cl := List(cl, Representative);
     cl := Filtered(cl, x -> Order(x) in [1,p]);

     # construct a split extension for every conjugacy class
     return List(cl,
           x -> SplitExtensionPcpGroup(AbelianPcpGroup(1,[p]),[x]));
end;

gap> SpecialSplitExtensions(2);
[ Pcp-group with orders [ 2, 2, 2, 2, 2 ],
   Pcp-group with orders [ 2, 2, 2, 2, 2 ],
   Pcp-group with orders [ 2, 2, 2, 2, 2 ] ]
gap> List(last, SchurMultiplicator);
[ [ 2, 2, 2, 2, 2, 2, 2, 2, 2, 2 ], [ 2, 2, 2, 2, 2, 2 ], [ 2, 2, 2, 2 ] ]
gap> SpecialSplitExtensions(3);
[ Pcp-group with orders [ 3, 3, 3, 3, 3 ],
   Pcp-group with orders [ 3, 3, 3, 3, 3 ],
   Pcp-group with orders [ 3, 3, 3, 3, 3 ],
   Pcp-group with orders [ 3, 3, 3, 3, 3 ] ]
gap> List(last, SchurMultiplicator);
[ [ 3, 3, 3, 3, 3, 3, 3, 3, 3, 3 ], [ 3, 3, 3, 3, 3, 3, 3 ],
   [ 3, 3, 3, 3, 3, 3 ], [ 3, 3, 3 ] ]
gap> SpecialSplitExtensions(5);
[ Pcp-group with orders [ 5, 5, 5, 5, 5 ],
   Pcp-group with orders [ 5, 5, 5, 5, 5 ],
   Pcp-group with orders [ 5, 5, 5, 5, 5 ],
   Pcp-group with orders [ 5, 5, 5, 5, 5 ],
   Pcp-group with orders [ 5, 5, 5, 5, 5 ] ]
gap> List(last, SchurMultiplicator);
[ [ 5, 5, 5, 5, 5, 5, 5, 5, 5, 5 ], [ 5, 5, 5, 5, 5, 5, 5 ],
   [ 5, 5, 5, 5, 5, 5 ], [ 5, 5, 5, 5 ], [ 5, 5, 5 ] ]


On Mon, 13 Sep 2010, Elaheh khamseh wrote:

> Dears
>
> Let G be a semidirect product of  a normal subgroup elementery abelian
> group of order p^4 and a cyclic group of order p. How can I copmute
> its Schur multiplier ?
>
>
> Do we have any information about the Schur multiplier of non-abelian
> p-groups of order p^5?
>
> Yours;
> E. Khamseh.
>
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum
>