[GAP Forum] Natural action of automorphism group on subsets

[Alexander Hulpke]

Dear Forum,

On Jan 12, 2010, at 2:44 PM, azhvan sanna wrote:

> Is there any function already defined for computing the orbits of natural action of automorphism group of a group on the subset of group?
> in another way, if you have given a group G, and a subset S of G, is there any function for computing like Orbits(Aut(G), S, OnSets) which gives us the {S^sigma| for sigma in Aut(G)}.

You're almost there, though I'm not sure from your formulation whether you want all orbits on a subset, or the orbit of a subset.

To have all orbits, use Orbits(autgrp,subset,OnPoints); (Example 1).
to get the orbit of a subset, use Orbit(autgrp,s,OnSets). Make sure that the set is sorted (Example 2)
If you want the orbits on subsets, you first would have to create the subsets and then use
Orbits(autgrp,subsets,OnSets);

Regards,

    Alexander Hulpke

-- Colorado State University, Department of Mathematics,
Weber Building, 1874 Campus Delivery, Fort Collins, CO 80523-1874, USA
email: hulpke at math.colostate.edu, Phone: ++1-970-4914288
http://www.math.colostate.edu/~hulpke

Example1:

gap> g:=SymmetricGroup(5);
Sym( [ 1 .. 5 ] )
gap> a:=AutomorphismGroup(g);
<group with 2 generators>
gap> s:=Filtered(Elements(g),x->not x in DerivedSubgroup(g));
[ (4,5), (3,4), (3,5), (2,3), (2,3,4,5), (2,3,5,4), (2,4,5,3), (2,4), 
  (2,4,3,5), (2,5,4,3), (2,5), (2,5,3,4), (1,2), (1,2)(3,4,5), (1,2)(3,5,4), 
  (1,2,3)(4,5), (1,2,3,4), (1,2,3,5), (1,2,4,3), (1,2,4,5), (1,2,4)(3,5), 
  (1,2,5,3), (1,2,5,4), (1,2,5)(3,4), (1,3,2)(4,5), (1,3,4,2), (1,3,5,2), 
  (1,3), (1,3,4,5), (1,3,5,4), (1,3)(2,4,5), (1,3,2,4), (1,3,5)(2,4), 
  (1,3)(2,5,4), (1,3,2,5), (1,3,4)(2,5), (1,4,3,2), (1,4,5,2), (1,4,2)(3,5), 
  (1,4,5,3), (1,4), (1,4,3,5), (1,4,2,3), (1,4,5)(2,3), (1,4)(2,3,5), 
  (1,4,3)(2,5), (1,4)(2,5,3), (1,4,2,5), (1,5,3,2), (1,5,4,2), (1,5,2)(3,4), 
  (1,5,4,3), (1,5), (1,5,3,4), (1,5,2,3), (1,5,4)(2,3), (1,5)(2,3,4), 
  (1,5,3)(2,4), (1,5)(2,4,3), (1,5,2,4) ]
gap> Orbits(a,s,OnPoints);
[ [ (4,5), (1,5), (1,2), (2,5), (2,3), (1,3), (3,4), (2,4), (3,5), (1,4) ], 
  [ (2,3,4,5), (1,3,4,5), (1,2,4,5), (1,2,3,5), (1,4,5,2), (1,2,3,4), 
      (1,3,5,2), (1,3,2,5), (1,3,4,2), (1,3,2,4), (1,2,4,3), (1,5,2,3), 
      (2,4,5,3), (2,4,3,5), (1,4,2,3), (2,3,5,4), (1,4,3,2), (1,4,3,5), 
      (1,4,5,3), (1,3,5,4), (2,5,3,4), (1,5,3,4), (2,5,4,3), (1,2,5,4), 
      (1,4,2,5), (1,5,2,4), (1,5,4,3), (1,5,4,2), (1,2,5,3), (1,5,3,2) ], 
  [ (1,2)(3,4,5), (1,4,5)(2,3), (1,2,5)(3,4), (1,3)(2,4,5), (1,2,3)(4,5), 
      (1,5,2)(3,4), (1,3,5)(2,4), (1,5)(2,3,4), (1,3,2)(4,5), (1,2,4)(3,5), 
      (1,4)(2,3,5), (1,3,4)(2,5), (1,5)(2,4,3), (1,4,2)(3,5), (1,2)(3,5,4), 
      (1,4,3)(2,5), (1,4)(2,5,3), (1,5,4)(2,3), (1,3)(2,5,4), (1,5,3)(2,4) ] ]

Example 2:
gap> s:=Set([(1,2,3),(1,3,2)]);
[ (1,2,3), (1,3,2) ]
gap> Orbit(a,s,OnSets);
[ [ (1,2,3), (1,3,2) ], [ (2,3,4), (2,4,3) ], [ (3,4,5), (3,5,4) ], 
  [ (1,3,4), (1,4,3) ], [ (1,4,5), (1,5,4) ], [ (2,4,5), (2,5,4) ], 
  [ (1,2,5), (1,5,2) ], [ (1,3,5), (1,5,3) ], [ (1,2,4), (1,4,2) ], 
  [ (2,3,5), (2,5,3) ] ]

Example 3:

gap> g:=DihedralGroup(IsPermGroup,8);
Group([ (1,2,3,4), (2,4) ])
gap> a:=AutomorphismGroup(g);
<group of size 8 with 3 generators>
gap> s:=Combinations(Elements(g),2); # all 2-element subsets
[ [ (), (2,4) ], [ (), (1,2)(3,4) ], [ (), (1,2,3,4) ], [ (), (1,3) ], 
  [ (), (1,3)(2,4) ], [ (), (1,4,3,2) ], [ (), (1,4)(2,3) ], 
[...]
gap> Orbits(a,s,OnSets); 
[ [ [ (), (2,4) ], [ (), (1,2)(3,4) ], [ (), (1,3) ], [ (), (1,4)(2,3) ] ], 
  [ [ (), (1,2,3,4) ], [ (), (1,4,3,2) ] ], [ [ (), (1,3)(2,4) ] ], 
  [ [ (2,4), (1,2)(3,4) ], [ (1,2)(3,4), (1,3) ], [ (1,3), (1,4)(2,3) ], 
      [ (2,4), (1,4)(2,3) ] ], 
  [ [ (2,4), (1,2,3,4) ], [ (1,2)(3,4), (1,2,3,4) ], [ (1,2,3,4), (1,3) ], 
      [ (2,4), (1,4,3,2) ], [ (1,2,3,4), (1,4)(2,3) ], 
      [ (1,4,3,2), (1,4)(2,3) ], [ (1,3), (1,4,3,2) ], 
      [ (1,2)(3,4), (1,4,3,2) ] ], 
  [ [ (2,4), (1,3) ], [ (1,2)(3,4), (1,4)(2,3) ] ], 
  [ [ (2,4), (1,3)(2,4) ], [ (1,2)(3,4), (1,3)(2,4) ], [ (1,3), (1,3)(2,4) ], 
      [ (1,3)(2,4), (1,4)(2,3) ] ], 
  [ [ (1,2,3,4), (1,3)(2,4) ], [ (1,3)(2,4), (1,4,3,2) ] ], 
  [ [ (1,2,3,4), (1,4,3,2) ] ] ]