[GAP Forum] How to find the value of a character over some
element in a group
azhvan sanna
azhvan at hotmail.com
Fri Jul 10 21:18:46 BST 2009
Dear GAP Forum,
Thanks for you answers, I can say I got disappointed for sporadic groups other than Mathieu groups, as there is no way I can find out about uniquely which columns correspond to the value of my specific character on the given elements.
Basically I have to evaluate something like " Sigma_{g1, g2,..,gt} Xi(g1.g2.g3...gt) " for each Xi in Irr(G) and t from 1 to the degree of Xi.
So I need to find a way to calculate the "Xi(g1.g2.g3...gt)" quickly.
Is there any idea?
Cheers,
Azhvan
> Date: Wed, 8 Jul 2009 10:20:02 +0200
> From: thomas.breuer at math.rwth-aachen.de
> To: forum at gap-system.org
> Subject: Re: [GAP Forum] How to find the value of character over generators
> CC:
>
> Dear GAP Forum,
>
> azhvan sanna wrote
>
> > I have to use the character table of sporadic simple groups, and evaluate the
> > value of characters on some specific generators, I appreciate if somebody tell
> > me; is this possible? I have got the idea that as we do not know about the
> > Conjugacy classes ordering and the nature of them used for making characters
> > table, so characters table can be used when we do some calculation regardless
> > of element involve in evaluating, so computing for example the value of one
> > character in some element seems not possible.
>
> 1. If one has computed a character table from a group in GAP
> then the bijection between the columns of the table
> and the conjugacy classes of this group is explicitly stored.
> In this situation, a given character <chi> can be evaluated at a
> group element <g> using <g>^<chi>, as in the following example.
>
> gap> G:= AlternatingGroup( 5 );;
> gap> g:= (1,2,3,4,5);;
> gap> tbl:= CharacterTable( G );;
> gap> Display( tbl );
> CT1
>
> 2 2 2 . . .
> 3 1 . 1 . .
> 5 1 . . 1 1
>
> 1a 2a 3a 5a 5b
> 2P 1a 1a 3a 5b 5a
> 3P 1a 2a 1a 5b 5a
> 5P 1a 2a 3a 1a 1a
>
> X.1 1 1 1 1 1
> X.2 3 -1 . A *A
> X.3 3 -1 . *A A
> X.4 4 . 1 -1 -1
> X.5 5 1 -1 . .
>
> A = -E(5)-E(5)^4
> = (1-ER(5))/2 = -b5
> gap> chi:= Irr( tbl )[2];
> Character( CharacterTable( Alt( [ 1 .. 5 ] ) ),
> [ 3, -1, 0, -E(5)-E(5)^4, -E(5)^2-E(5)^3 ] )
> gap> g^chi;
> -E(5)-E(5)^4
>
> Note that in this situation GAP has to find out in which conjugacy class
> of the group the given element lies.
> So if one wants to evaluate several characters of a given character table
> at the same group element, it is more efficient to compute once in which
> conjugacy class this element lies, and then to fetch the character value
> at the position of this class.
>
> gap> pos:= PositionProperty( ConjugacyClasses( tbl ), C -> g in C );
> 4
> gap> chi[ pos ];
> -E(5)-E(5)^4
>
> 2. The situation is different if the bijection of table columns and
> conjugacy classes is not explicitly known.
> The question was about sporadic simple groups, the character tables
> of these groups are printed in the famous Atlas of Finite Groups,
> and these Atlas tables are available in GAP's Library of Character Tables.
> Let us assume we are interested in the Mathieu group M_{11}.
> Its Atlas character table can be fetched as follows.
>
> gap> tbl:= CharacterTable( "M11" );
> CharacterTable( "M11" )
> gap> Display( tbl );
> M11
>
> 2 4 4 1 3 . 1 3 3 . .
> 3 2 1 2 . . 1 . . . .
> 5 1 . . . 1 . . . . .
> 11 1 . . . . . . . 1 1
>
> 1a 2a 3a 4a 5a 6a 8a 8b 11a 11b
> 2P 1a 1a 3a 2a 5a 3a 4a 4a 11b 11a
> 3P 1a 2a 1a 4a 5a 2a 8a 8b 11a 11b
> 5P 1a 2a 3a 4a 1a 6a 8b 8a 11a 11b
> 11P 1a 2a 3a 4a 5a 6a 8a 8b 1a 1a
>
> X.1 1 1 1 1 1 1 1 1 1 1
> X.2 10 2 1 2 . -1 . . -1 -1
> X.3 10 -2 1 . . 1 A -A -1 -1
> X.4 10 -2 1 . . 1 -A A -1 -1
> X.5 11 3 2 -1 1 . -1 -1 . .
> X.6 16 . -2 . 1 . . . B /B
> X.7 16 . -2 . 1 . . . /B B
> X.8 44 4 -1 . -1 1 . . . .
> X.9 45 -3 . 1 . . -1 -1 1 1
> X.10 55 -1 1 -1 . -1 1 1 . .
>
> A = E(8)+E(8)^3
> = ER(-2) = i2
> B = E(11)+E(11)^3+E(11)^4+E(11)^5+E(11)^9
> = (-1+ER(-11))/2 = b11
>
> If we are now given a representation of the group M_{11} and want to
> use the Atlas character table together with this concrete group
> then the bijection between the conjugacy classes of the group and the
> columns of the Atlas table is not known.
> For the first six columns of the table, the element orders determine
> the corresponding conjugacy class uniquely,
> but for an element of order 8 or 11, it is not clear to which column
> of the table its conjugacy class corresponds.
>
> In this example, there is in fact no problem because of symmetries
> of the character table, which allow one to choose any column of the
> appropriate element order as the one that corresponds to a given element.
> (But after that choice, the correspondence is of course fixed.)
>
> In general, it may happen that the correspondence between the classes
> of a given group and the columns of the character table of this group
> cannot be determined uniquely (up to symmetries of the table) without
> additional information.
> In the worst case, one may be forced to recompute (parts of) the character
> table from the group.
> However, often this is not necessary, and one does in fact not need the
> complete information about the correspondence between classes and columns.
>
> 3. The question was about sporadic simple groups,
> and for most of these groups, the Atlas of Group Representations
> (see http://brauer.maths.qmul.ac.uk/Atlas/)
> provides a program for computing standard conjugacy class representatives,
> if one starts with standard generators of the group in question.
> In GAP, one can access this information via the package AtlasRep,
> as follows.
> We choose the degree 11 permutation representation of the Mathieu group
> M_{11}.
>
> gap> LoadPackage( "atlasrep" );
> true
> gap> prg:= AtlasStraightLineProgram( "M11", "classes" );;
> gap> info:= OneAtlasGeneratingSetInfo( "M11" );;
> gap> gens:= AtlasGenerators( info );;
> gap> reps:= ResultOfStraightLineProgram( prg.program, gens.generators );
> [ (), (2,10)(4,11)(5,7)(8,9), (2,6,10)(4,8,7)(5,9,11),
> (1,4,3,8)(2,5,6,9), (2,5,3,7,10)(4,6,11,8,9),
> (1,3)(2,10,6)(4,11,8,5,7,9), (1,8,6,11,3,7,10,9)(4,5),
> (1,7,6,9,3,8,10,11)(4,5), (1,4,11,3,8,2,10,5,7,6,9),
> (1,8,6,5,7,2,10,9,3,4,11) ]
>
> The class representatives obtained this way correspond to the columns of
> the Atlas character table of the group M_{11}.
>
> 4. More information about character tables in GAP can be found in the
> GAP Reference Manual, see for example
> http://www.gap-system.org/Manuals/doc/htm/ref/CHAP069.htm
> or try `?Character Tables' in GAP.
>
> All the best,
> Thomas
>
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum
_________________________________________________________________
Stay in the loop and chat with friends, right from your inbox!
http://go.microsoft.com/?linkid=9671354
More information about the Forum
mailing list