[GAP Forum] Re: p-group of maximal class

Mowsey gapforum at mowsey.org
Thu Nov 4 22:18:45 GMT 2004


My apologies in advance for such a partial reply.  I still don't
know enough about groups of maximal class to be very useful.

All p-groups of maximal class are descendents of a group of maximal
class from a particular family, and the descendents can be described
fairly explicitly by twistings.  This is described in chapter 8
of Leedham-Green and McKay's "Structure of Groups of Prime Power
Order". Prof. Eick has made these descriptions concrete in her
paper "On the determination of the uniserial space groups with a
given coclass."

I have not myself been able to construct all groups of maximal
class, but I have written a very simple routine to generate the
infinite family. Perhaps it may help to at least have one example
of every order, though this is obviously a far cry from having
all such groups.

# pHedralGroupCons(p,n) returns a group of order p^n and nilpotency
# class p^(n-1). See Leedham-Green&McKay, example 3.1.5.ii, example
# 7.4.14.i, and proposition 8.2.3.iii

pHedralGroupCons:=function(p,n)
        local F,rels,i,j,gens;
        F:=FreeGroup(IsSyllableWordsFamily,n+1);
        gens:=GeneratorsOfGroup(F);
        gens:=Concatenation(gens,ListWithIdenticalEntries(p+1,One(F)));
        rels:=[];
        Add(rels,gens[1]^p);
        for i in [2..n+1] do Add(rels,gens[i]^p/gens[i+p-1]); od;
        for i in [2..n+1] do
                if(1 = i mod (p-1) or p=2) then Add(rels, Comm(gens[i],gens[1])*
                        Product(List([i+2-p..i],j->gens[j+p-1]^(Binomial(p,1+(j-2) mod (p-1))/p))));
                else Add(rels,Comm(gens[i],gens[1])/gens[i+1]);
                fi;
                for j in [2..i-1] do Add(rels,Comm(gens[i],gens[j])); od;
        od;
        rels:=Filtered(rels,x->not IsOne(x));
        return RefinedPcGroup(PcGroupFpGroup(F/rels));
end;





More information about the Forum mailing list